Nightwing

Heidenhain iTNC 530

Hier findest Du einige Parameterprogramme für Fräsmaschinen mit der Heidenhain iTNC 530 Steuerung. Für tägliche und sich oft wiederholende Bearbeitungen kann man sich schonmal das Leben erleichtern.

Abzeilen Kontur mit einem Werkzeug

Dieses kleine Programm ist gut, um beispielsweise Plattenmaterial / Ebenen zu überfräsen. Nach dem ersten Durchlauf der Kontur kann man getrost einen Kaffee trinken gehen.

Code eingefügt. Hier klicken zum Ein- / Ausblenden
0  BEGIN PGM Abzeilen Kontur 1 WKZ MM 
1  BLK FORM 0.1 Z  X-1183  Y-80  Z-70
2  BLK FORM 0.2  X+0  Y+0  Z+0
3  * - 4 TEILE
7  ;
8  ; Variablen fuer Fraesen definieren
9  ;
10 Q602 = - 228 ; Anfangspunkt X
11 Q603 = 35 ; Anfangspunkt Y
12 Q604 = - 1.5 ; Anfangspunkt Z
13 Q605 = - 19 ; Endpunkt Z
14 Q606 = 1.5 ; Zustellung Z
15 Q607 = Q604 + 5 ; Sicherheitsabstand Z
16 Q608 = 50 ; 2. Sicherheitsabstand Z
17 Q610 = 31 ; Werkzeug
18 Q611 = 250 ; Vc
19 Q614 = 1000 ; Vorschub Zustellung
20 Q615 = 900 ; Vorschub
21 Q618 = 7 ; M Befehl Innenkuehlung
22 ;
23 FN 9: IF +0 EQU +0 GOTO LBL "FRAESEN"
24 ;
25 ; Konturzug fuer Fraesen definieren
26 ; ( X / Y / RL / RR )
27 ;
28 LBL "KONTUR"
29 L  Y-115
30 L  Y-60
31 L  X-1028
32 L  Y-115
33 L  Y+35
34 L  Y-20
35 L  X-228
36 L  Y+35
37 ;
38 ; Ab hier nichts mehr aendern!!
39 ;
40 FN 9: IF +0 EQU +0 GOTO LBL "CONTINUE"
41 LBL "FRAESEN"
42 TOOL CALL Q610 Z S( VC = Q611 )
43 CYCL DEF 301 ~
    Q1998=+1
44 L  X+Q602  Y+Q603 FMAX M3
45 L  Z+Q607 FMAX MQ618
46 L  Z+Q604 FQ614
47 L FQ615
48 FN 9: IF +0 EQU +0 GOTO LBL "KONTUR"
49 LBL "CONTINUE"
50 L  Z+Q608 R0 FMAX
51 FN 9: IF +Q604 EQU +Q605 GOTO LBL "ENDE"
52 Q604 = Q604 - Q606
53 Q607 = Q607 - Q606
54 FN 11: IF +Q604 GT +Q605 GOTO LBL "FRAESEN"
55 Q604 = Q605
56 Q607 = Q604 + 5
57 FN 9: IF +0 EQU +0 GOTO LBL "FRAESEN"
58 LBL "ENDE"
59 L  Z+Q608 FMAX M9 M0
60 TOOL CALL 32 Z S100
61 CYCL DEF 301 ~
    Q1998=+1
62 L  X+500  Y+70 FMAX M30
63 END PGM Abzeilen Kontur 1 WKZ MM

Hier habe ich das Programm noch modifiziert, um in X Richtung beidseitig eine Kontur zu fräsen. In diesem Beispiel werden 2 Platten an einem Schweissteil überfräst.

Code eingefügt. Hier klicken zum Ein- / Ausblenden
0  BEGIN PGM Kontur X beidseitig MM 
1  BLK FORM 0.1 Z  X-5  Y-150  Z-150
2  BLK FORM 0.2  X+2050  Y+150  Z+150
3  ;
4  LBL "VARDEF"
5  Q1 = 2050 ; NPV in X
6  LBL 0
7  ;
8  ; Kontur Links
9  ;
10 Q602 = 125 ; Anfangspunkt X
11 Q603 = 225 ; Anfangspunkt Y
12 Q604 = 5.7 ; Anfangspunkt Z
13 Q605 = 0 ; Endpunkt Z
14 Q606 = 0.6 ; Zustellung Z
15 Q607 = Q604 + 5 ; Sicherheitsabstand Z
16 Q608 = 50 ; 2. Sicherheitsabstand Z
17 Q610 = 30 ; Werkzeug
18 Q611 = 250 ; Vc
19 Q614 = 1000 ; Vorschub Zustellung
20 Q615 = 600 ; Vorschub
21 Q618 = 17 ; M Befehl Innenkuehlung
22 ;
23 FN 9: IF +0 EQU +0 GOTO LBL "FRAESEN-L"
24 ;
25 ; Kontur Links
26 ; ( X / Y / RL / RR )
27 ;
28 LBL "KONTUR-L"
29 L  Y-225 F AUTO
30 L IZ+50 FMAX
31 L  X+45  Y+225 FMAX
32 L IZ-50 FMAX
33 L  Y-225 F AUTO
34 L IZ+50 FMAX
35 L  X-45  Y+225 FMAX
36 L IZ-50 FMAX
37 L  Y-225 F AUTO
38 L IZ+50 FMAX
39 L  X-125  Y+225 FMAX
40 L IZ-50 FMAX
41 L  Y-225 F AUTO
42 ;
43 ; Ab hier nichts mehr aendern!!
44 ;
45 FN 9: IF +0 EQU +0 GOTO LBL "CONTINUE-L"
46 LBL "FRAESEN-L"
47 TOOL CALL Q610 Z S( VC = Q611 ) ~
    FQ615
48 CYCL DEF 304 ~
    Q1994=-90 ~
    Q1998=+1 ~
    Q1999=+1
49 L  Z+Q608 FMAX
50 L  X+Q602  Y+Q603 FMAX M3
51 L  Z+Q607 FMAX MQ618
52 L  Z+Q604 FQ614
53 FN 9: IF +0 EQU +0 GOTO LBL "KONTUR-L"
54 LBL "CONTINUE-L"
55 L  Z+Q608 R0 FMAX
56 FN 9: IF +Q604 EQU +Q605 GOTO LBL "NEXT"
57 Q604 = Q604 - Q606
58 Q607 = Q607 - Q606
59 FN 11: IF +Q604 GT +Q605 GOTO LBL "FRAESEN-L"
60 Q604 = Q605
61 Q607 = Q604 + 5
62 FN 9: IF +0 EQU +0 GOTO LBL "FRAESEN-L"
63 LBL "NEXT"
64 ;
65 ; Kontur Rechts
66 ;
67 Q702 = - 175 ; Anfangspunkt X
68 Q703 = - 155 ; Anfangspunkt Y
69 Q704 = 5.7 ; Anfangspunkt Z
70 Q705 = 0 ; Endpunkt Z
71 Q706 = 0.6 ; Zustellung Z
72 Q707 = Q704 + 5 ; Sicherheitsabstand Z
73 Q708 = 50 ; 2. Sicherheitsabstand Z
74 Q710 = 30 ; Werkzeug
75 Q711 = 250 ; Vc
76 Q714 = 1000 ; Vorschub Zustellung
77 Q715 = 600 ; Vorschub
78 Q718 = 17 ; M Befehl Innenkuehlung
79 ;
80 FN 9: IF +0 EQU +0 GOTO LBL "FRAESEN-R"
81 ;
82 ; Kontur Rechts
83 ; ( X / Y / RL / RR )
84 ;
85 LBL "KONTUR-R"
86 L  Y+155 F AUTO
87 L IZ+50 FMAX
88 L  X-125  Y-155 FMAX
89 L IZ-50 FMAX
90 L  Y+155 F AUTO
91 L IZ+50 FMAX
92 L  X-75  Y-155 FMAX
93 L IZ-50 FMAX
94 L  Y+155 F AUTO
95 L IZ+50 FMAX
96 L  X-25  Y-155 FMAX
97 L IZ-50 FMAX
98 L  Y+155 F AUTO
99 L IZ+50 FMAX
100 L  X+30  Y-155 FMAX
101 L IZ-50 FMAX
102 L  Y+155 F AUTO
103 L IZ+50 FMAX
104 L  X+80  Y-155 FMAX
105 L IZ-50 FMAX
106 L  Y+155 F AUTO
107 L IZ+50 FMAX
108 L  X+135  Y-155 FMAX
109 L IZ-50 FMAX
110 L  Y+155 F AUTO
111 ;
112 ; Ab hier nichts mehr aendern!!
113 ;
114 FN 9: IF +0 EQU +0 GOTO LBL "CONTINUE-R"
115 LBL "FRAESEN-R"
116 TOOL CALL Q710 Z S( VC = Q711 ) ~
    FQ715
117 CALL LBL "NPV"
118 CYCL DEF 304 ~
    Q1994=+90 ~
    Q1998=+1 ~
    Q1999=+1
119 L  Z+Q708 FMAX
120 L  X+Q702  Y+Q703 FMAX M3
121 L  Z+Q707 FMAX MQ718
122 L  Z+Q704 FQ714
123 FN 9: IF +0 EQU +0 GOTO LBL "KONTUR-R"
124 LBL "CONTINUE-R"
125 L  Z+Q708 R0 FMAX
126 FN 9: IF +Q704 EQU +Q705 GOTO LBL "ENDE"
127 Q704 = Q704 - Q706
128 Q707 = Q707 - Q706
129 FN 11: IF +Q704 GT +Q705 GOTO LBL "FRAESEN-R"
130 Q704 = Q705
131 Q707 = Q704 + 5
132 FN 9: IF +0 EQU +0 GOTO LBL "FRAESEN-R"
133 LBL "ENDE"
134 CALL LBL "NPV-RESET"
135 TOOL CALL 32 Z S100
136 CYCL DEF 301 ~
    Q1998=+1
137 L  X+1250  Y+425 FMAX M30
138 LBL "NPV"
139 CALL LBL "VARDEF"
140 CYCL DEF 19.0 BEARBEITUNGSEBENE
141 CYCL DEF 19.1  B+0
142 CYCL DEF 7.0 NULLPUNKT
143 CYCL DEF 7.1  X+Q1
144 LBL 0
145 LBL "NPV-RESET"
146 CYCL DEF 19.0 BEARBEITUNGSEBENE
147 CYCL DEF 19.1  B+0
148 CYCL DEF 7.0 NULLPUNKT
149 CYCL DEF 7.1  X+0
150 LBL 0
151 END PGM Kontur X beidseitig MM

Zurück