Heidenhain iTNC 530

Hier findest Du einige Parameterprogramme für Fräsmaschinen mit der Heidenhain iTNC 530 Steuerung. Für tägliche und sich oft wiederholende Bearbeitungen kann man sich schonmal das Leben erleichtern.

Abzeilen Kontur

Dieses kleine Programm eignet sich prima um z.B. eine Kontur abzufräsen, mit anschliessendem Schlichten, oder einfach nur um eine Platte mehrfach auf Mass zu Überfräsen. Der Phantasie sind da (fast) keine Grenzen gesetzt.

Code eingefügt. Hier klicken zum Ein- / Ausblenden
0  BEGIN PGM abzeilen_kontur MM 
1  BLK FORM 0.1 Z  X-4.5  Y-180  Z-40
2  BLK FORM 0.2  X+993  Y+0  Z+0
3  ;
4  ; Variablen fuer Fraesen definieren
5  ;
6  Q602 = 35 ; Anfangspunkt X
7  Q603 = - 15 ; Anfangspunkt Y
8  Q604 = 20 ; Anfangspunkt Z
9  Q605 = 0 ; Endpunkt Z
10 Q606 = 1.5 ; Zustellung Z
11 Q607 = Q604 + 5 ; Sicherheitsabstand Z
12 Q608 = 50 ; 2. Sicherheitsabstand Z
13 Q609 = 0.3 ; Schlichtaufmass
14 Q610 = 1 ; Werkzeug Schruppen
15 Q611 = 250 ; Vc Schruppen
16 Q612 = 2 ; Werkzeug Schlichten
17 Q613 = 250 ; Vc Schlichten
18 Q614 = 1000 ; Vorschub Zustellung
19 Q615 = 1500 ; Vorschub Schruppen
20 Q616 = 1000 ; Vorschub Schlichten
21 Q617 = 8 ; M Befehl Kuehlung
22 Q618 = 7 ; M Befehl Innenkuehlung
23 Q619 = 17 ; M Befehl Blasluft
24 ;
25 FN 9: IF +0 EQU +0 GOTO LBL "SCHRUPPEN"
26 ;
27 ; Konturzug fuer Fraesen definieren
28 ; ( X / Y / RL / RR )
29 ;
30 LBL "KONTUR"
31   F AUTO
32 L  X-40 F AUTO
33 L IY-16 RL
34 L  X+30 RL
35 L IY+32 RL
36 L  X-40 RL
37 L IZ+100 R0 FMAX
38 L  X+20  Y-172 FMAX
39 L IZ-100 FMAX
40 L  X-40 F AUTO
41 L IY-16 RL
42 L  X+30 RL
43 L IY+32 RL
44 L  X-40 RL
45 ;
46 ; Ab hier nichts mehr aendern!!
47 ;
48 FN 9: IF +0 EQU +0 GOTO LBL "CONTINUE"
49 LBL "SCHRUPPEN"
50 TOOL CALL Q610 Z S( VC = Q611 ) ~
    FQ615 DL+Q609 DR+Q609
51 CYCL DEF 301 ~
    Q1998=+1
52 L  X+Q602  Y+Q603 FMAX M3
53 L  Z+Q607 FMAX MQ619
54 L  Z+Q604 FQ614
55 FN 9: IF +0 EQU +0 GOTO LBL "KONTUR"
56 LBL "SCHLICHTEN"
57 LBL "PLACEHOLDER"
58 ;
59 ; zusaetzliche Bearbeitung (Stirn)
60 ;
61 CYCL DEF 304 ~
    Q1994=-90 ~
    Q1998=+1 ~
    Q1999=+1
62 L  Z+50 FMAX
63 L  X+100 FMAX
64 L  X-40  Y+20 FMAX M3
65 L  Z+5 FMAX
66 L  Z-15 F1000
67 L  X-13 RR F AUTO
68 L  Y-80 RR F AUTO
69 L  Z+50 R0 FMAX
70 LBL 0
71 Q620 = 1
72 TOOL CALL Q612 Z S( VC = Q613 ) ~
    FQ616
73 CYCL DEF 301 ~
    Q1998=+1
74 Q604 = Q605
75 Q607 = Q604 + 5
76 L  X+Q602  Y+Q603 FMAX M3 MQ617
77 L  Z+Q607 FMAX MQ618
78 L  Z+Q604 FQ614
79 FN 9: IF +0 EQU +0 GOTO LBL "KONTUR"
80 LBL "CONTINUE"
81 L  Z+Q608 R0 FMAX
82 FN 9: IF +Q620 EQU +1 GOTO LBL "ENDE"
83 FN 9: IF +Q604 EQU +Q605 GOTO LBL "SCHLICHTEN"
84 Q604 = Q604 - Q606
85 Q607 = Q607 - Q606
86 FN 11: IF +Q604 GT +Q605 GOTO LBL "SCHRUPPEN"
87 Q604 = Q605
88 Q607 = Q604 + 5
89 FN 9: IF +0 EQU +0 GOTO LBL "SCHRUPPEN"
90 LBL "ENDE"
91 CALL LBL "PLACEHOLDER"
92 TOOL CALL 0 Z S100
93 L  X+250 IY-250 FMAX M30
94 END PGM abzeilen_kontur MM 

Zurück