Nightwing

Heidenhain iTNC 530

Hier findest Du einige Parameterprogramme für Fräsmaschinen mit der Heidenhain iTNC 530 Steuerung. Für tägliche und sich oft wiederholende Bearbeitungen kann man sich schonmal das Leben erleichtern.

Nächster Eintrag »

Abfrage für Bearbeitung

Hier eine simple kleine Abfrage, ob eine bestimmte Bearbeitung ausgeschlossen werden soll. Beispiel wäre: Rohmaterial einmal geschliffen, einmal muss es bearbeitet werden:

abfrage_bearbeitung.h

Code eingefügt. 
0  BEGIN PGM Abfrage Bearbeitung MM 
1  BLK FORM 0.1 Z  X-140  Y-150  Z-15
2  BLK FORM 0.2  X+1.5  Y+0  Z+0
3  ;
4  Q1 = 1 ; Auswahl Bearbeitung
5  ;
6  ; Nur Kontur fraesen --> Q1 = 0
7  ; Kontur + Bohrungen --> Q1 = 1
8  ;
9  LBL "FRAESEN"
10 TOOL CALL 1 Z S( VC = 250 ) ~
    F1500 DL+0.3 DR+0.3
11 * - HPC 20 SR
12 M17
13 LBL "NULLKANTE"
14 CYCL DEF 301 ~
    Q1998=+1
15 L  X+20  Y+20 FMAX M3
16 L  Z+5 FMAX
17 L  Z-25 F1000
18 L  X-15  Y+5 RL F AUTO
19 L  X+0  Y-10
20 L  Y-130
21 L  X-25  Y-155
22 L  Z+50 R0 FMAX
23 LBL 0
24 TOOL CALL 2 Z S( VC = 250 ) ~
    F1000
25 * - HPC 20 SL
26 M7 M8
27 CALL LBL "NULLKANTE"
28 ;
29 FN 9: IF +Q1 EQU +0 GOTO LBL "ENDE"
30 FN 9: IF +Q1 EQU +1 GOTO LBL "BOHREN"
31 ;
32 LBL "BOHREN"
33 TOOL CALL 3 Z S( VC = 100 )
34 * - VHM 11
35 CYCL DEF 200 BOHREN ~
    Q200=+5    ;SICHERHEITS-ABST. ~
    Q201=-20   ;TIEFE ~
    Q206= FU+0.2  ;VORSCHUB TIEFENZ. ~
    Q202=+20   ;ZUSTELL-TIEFE ~
    Q210=+0    ;VERWEILZEIT OBEN ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q211=+0    ;VERWEILZEIT UNTEN
36 M7 M8
37 LBL "D-12.5"
38 CYCL DEF 301 ~
    Q1998=+1
39 L  X-20  Y-20 FMAX M3 M99
40 L  X-120 FMAX M99
41 LBL 0
42 LBL "62J6"
43 CYCL DEF 301 ~
    Q1998=+1
44 L  X-70  Y-110 FMAX M3 M99
45 LBL 0
46 TOOL CALL 21 Z S( VC = 150 )
47 * - HPC 12 SR
48 M17
49 CYCL DEF 208 BOHRFRAESEN ~
    Q200=+5    ;SICHERHEITS-ABST. ~
    Q201=-17   ;TIEFE ~
    Q206=+800  ;VORSCHUB TIEFENZ. ~
    Q334=+1    ;ZUSTELL-TIEFE ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q335=+12.5 ;SOLL-DURCHMESSER ~
    Q342=+11   ;VORGEB. DURCHMESSER ~
    Q351=+1    ;FRAESART
50 CALL LBL "D-12.5"
51 CYCL DEF 208 BOHRFRAESEN ~
    Q200=+5    ;SICHERHEITS-ABST. ~
    Q201=-17   ;TIEFE ~
    Q206=+800  ;VORSCHUB TIEFENZ. ~
    Q334=+1    ;ZUSTELL-TIEFE ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q335=+25   ;SOLL-DURCHMESSER ~
    Q342=+11   ;VORGEB. DURCHMESSER ~
    Q351=+1    ;FRAESART
52 CALL LBL "62J6"
53 CYCL DEF 252 KREISTASCHE ~
    Q215=+2    ;BEARBEITUNGS-UMFANG ~
    Q223=+61.8 ;KREISDURCHMESSER ~
    Q368=+24.65 ;AUFMASS SEITE ~
    Q207=+800  ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-16   ;TIEFE ~
    Q202=+16   ;ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q206=+1000 ;VORSCHUB TIEFENZ. ~
    Q338=+16   ;ZUST. SCHLICHTEN ~
    Q200=+5    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+0.2  ;BAHN-UEBERLAPPUNG ~
    Q366=+0    ;EINTAUCHEN ~
    Q385=+800  ;VORSCHUB SCHLICHTEN
54 CALL LBL "62J6"
55 STOP M5 M9
56 TOOL CALL 28 Z S( VC = 125 )
57 * - ADW 62J6
58 CYCL DEF 202 AUSDREHEN ~
    Q200=+5    ;SICHERHEITS-ABST. ~
    Q201=-17   ;TIEFE ~
    Q206= FU+0.065 ;VORSCHUB TIEFENZ. ~
    Q211=+0    ;VERWEILZEIT UNTEN ~
    Q208= MAX ;VORSCHUB RUECKZUG ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q214=+1    ;FREIFAHR-RICHTUNG ~
    Q336=+140  ;WINKEL SPINDEL
59 M7 M8
60 CALL LBL "62J6"
61 LBL "ENDE"
62 TOOL CALL 32 Z S100
63 CYCL DEF 301 ~
    Q1998=+1
64 L  X+250  Y+70 FMAX M30
65 END PGM Abfrage Bearbeitung MM

Zurück