Nightwing

Heidenhain iTNC 530

Hier findest Du einige Parameterprogramme für Fräsmaschinen mit der Heidenhain iTNC 530 Steuerung. Für tägliche und sich oft wiederholende Bearbeitungen kann man sich schonmal das Leben erleichtern.

« Letzter Eintrag Nächster Eintrag »

Abzeilen von 2 / 3 Konturen

Hier ein kleines Programm, um 2 Konturen abzuzeilen / fräsen. Eignet sich gut, wenn man z.B. links und rechts je eine Kontur mehrfach fräsen muss.

abzeilen_2_konturen.h

Code eingefügt. 
0  BEGIN PGM Abzeilen 2 Konturen MM 
1  BLK FORM 0.1 Z  X-1  Y-20  Z-50
2  BLK FORM 0.2  X+1640  Y+0  Z+0
3  TOOL CALL 31 Z S( VC = 250 ) ~
    F900
4  * - EMK 50
5  CYCL DEF 301 ~
    Q1998=+1
6  Q1 = 1.5 ; Zustellung
7  Q2 = - 15 ; Endpunkt Z
8  L  X+610  Y+35 FMAX M3
9  L  Z+5 FMAX M17
10 Q3 = Q1 ; Tiefe Z
11 L  Z-Q3 F1000
12 LBL "KONTUR_1"
13 L  Y-55 F AUTO
14 L IX+35 RL F AUTO
15 L  Y+70 RL F AUTO
16 L IX-70 RL F AUTO
17 L  Y-55 RL F AUTO
18 L  Z+50 R0 FMAX
19 Q3 = Q3 + Q1 ; Zustellung
20 FN 11: IF +Q3 GT +Q2 GOTO LBL "NEXT"
21 L  X+610  Y+35 FMAX
22 L  Z+5 FMAX
23 L  Z-Q3 F1000
24 FN 9: IF +0 EQU +0 GOTO LBL "KONTUR_1"
25 LBL "NEXT"
26 Q4 = 1.5 ; Zustellung
27 Q5 = - 15 ; Endpunkt Z
28 L  X+1030  Y+35 FMAX
29 L  Z+5 FMAX
30 Q6 = Q4 ; Tiefe Z
31 L  Z-Q6 F1000
32 LBL "KONTUR_2"
33 L  Y-55 F AUTO
34 L IX+35 RL F AUTO
35 L  Y+70 RL F AUTO
36 L IX-70 RL F AUTO
37 L  Y-55 RL F AUTO
38 L  Z+50 R0 FMAX
39 Q6 = Q6 + Q4 ; Zustellung
40 FN 11: IF +Q6 GT +Q5 GOTO LBL "ENDE"
41 L  X+1030  Y+35 FMAX
42 L  Z+5 FMAX
43 L  Z-Q6 F1000
44 FN 9: IF +0 EQU +0 GOTO LBL "KONTUR_2"
45 LBL "ENDE"
46 TOOL CALL 32 Z S100
47 CYCL DEF 301 ~
    Q1998=+1
48 L  X+500  Y+70 FMAX M30
49 END PGM Abzeilen 2 Konturen MM

Und das Ganze noch auf 3 Konturen aufgebohrt:

abzeilen_3_konturen.h

Code eingefügt. 
0  BEGIN PGM Abzeilen 3 Konturen MM 
1  BLK FORM 0.1 Z  X-1390  Y-30  Z-160
2  BLK FORM 0.2  X+1  Y+0  Z+0
3  LBL "VARDEF"
4  ;
5  ; Kontur Rechts
6  ;
7  Q1001 = 57.6 ; Endtiefe Z
8  Q1002 = 32 ; Anzahl Zustellungen
9  Q1003 = Q1001 / Q1002 ; Berechnung Zustellung
10 ;
11 ; Kontur Mitte
12 ;
13 Q1011 = 57.6 ; Endtiefe Z
14 Q1012 = 32 ; Anzahl Zustellungen
15 Q1013 = Q1011 / Q1012 ; Berechnung Zustellung
16 ;
17 ; Kontur Links
18 ;
19 Q1021 = 57.6 ; Endtiefe Z
20 Q1022 = 32 ; Anzahl Zustellungen
21 Q1023 = Q1021 / Q1022 ; Berechnung Zustellung
22 ;
23 ; Konturen Schlichten
24 ;
25 Q901 = 57.6 ; Endtiefe Z
26 Q902 = 8 ; Anzahl Zustellungen
27 Q903 = Q901 / Q902 ; Berechnung Zustellung
28 LBL 0
29 ;
30 ;
31 ;
32 TOOL CALL 31 Z S( VC = 200 ) ~
    F900
33 * - EMK 50
34 ;
35 ; Kontur Rechts
36 ;
37 LBL "KONTURDATEN_R"
38 Q1004 = Q1003 ; Erste Zustellung Z
39 LBL "STARTPUNKT_R"
40 CALL LBL "VARDEF"
41 CYCL DEF 301 ~
    Q1998=+1
42 L  X+35  Y-15 FMAX M3
43 L  Z+5 FMAX M17
44 L  Z-Q1004 F1000
45 LBL 0
46 LBL "KONTUR_R"
47 L  X-124.7 F AUTO
48 L  Y-35 F AUTO
49 L  Y+5 F AUTO
50 L  Z+50 FMAX
51 Q1004 = Q1004 + Q1003 ; Neue Zustellung Z
52 FN 11: IF +Q1004 GT +Q1001 GOTO LBL "KONTURDATEN_M"
53 CALL LBL "STARTPUNKT_R"
54 FN 9: IF +0 EQU +0 GOTO LBL "KONTUR_R"
55 ;
56 ; Kontur Mitte
57 ;
58 LBL "KONTURDATEN_M"
59 Q1014 = Q1013 ; Erste Zustellung Z
60 LBL "STARTPUNKT_M"
61 CALL LBL "VARDEF"
62 CYCL DEF 301 ~
    Q1998=+1
63 L  X-665.2  Y+35 FMAX M3
64 L  Z+5 FMAX M17
65 L  Z-Q1014 F1000
66 LBL 0
67 LBL "KONTUR_M"
68 L  Y-35 F AUTO
69 L  Y-15 F AUTO
70 L  X-724.7 F AUTO
71 L  Y-35 F AUTO
72 L  Y+5 F AUTO
73 L  Z+50 FMAX
74 Q1014 = Q1014 + Q1013 ; Neue Zustellung Z
75 FN 11: IF +Q1014 GT +Q1011 GOTO LBL "KONTURDATEN_L"
76 CALL LBL "STARTPUNKT_M"
77 FN 9: IF +0 EQU +0 GOTO LBL "KONTUR_M"
78 ;
79 ; Kontur Links
80 ;
81 LBL "KONTURDATEN_L"
82 Q1024 = Q1023 ; Erste Zustellung Z
83 LBL "STARTPUNKT_L"
84 CALL LBL "VARDEF"
85 CYCL DEF 301 ~
    Q1998=+1
86 L  X-1425  Y-15 FMAX M3
87 L  Z+5 FMAX M17
88 L  Z-Q1024 F1000
89 LBL 0
90 LBL "KONTUR_L"
91 L  X-1265.2 F AUTO
92 L  Y+5 F AUTO
93 L  Y-35 F AUTO
94 L  Z+50 FMAX
95 Q1024 = Q1024 + Q1023 ; Neue Zustellung Z
96 FN 11: IF +Q1024 GT +Q1021 GOTO LBL "SCHLICHT"
97 CALL LBL "STARTPUNKT_L"
98 FN 9: IF +0 EQU +0 GOTO LBL "KONTUR_L"
99 LBL "SCHLICHT"
100 ;
101 ; Konturen Schlichten
102 ;
103 TOOL CALL 29 Z S( VC = 200 ) ~
    F500
104 * - HPC 20 LANG
105 Q904 = Q903 ; Erste Zustellung Z
106 LBL "SCHLICHTEN"
107 CALL LBL "VARDEF"
108 CYCL DEF 301 ~
    Q1998=+1
109 L  X-130  Y+20 FMAX M13
110 L  Z+5 FMAX
111 L  Z-Q904 F1000
112 L  X-150 RL F AUTO
113 L  Y-50 RL F AUTO
114 L  Z+50 R0 FMAX
115 L  X-730  Y+20 FMAX
116 L  Z+5 FMAX
117 L  Z-Q904 F1000
118 L  X-750 RL F AUTO
119 L  Y-50 RL F AUTO
120 L  Z+50 R0 FMAX
121 L  X-660  Y-50 FMAX
122 L  Z+5 FMAX
123 L  Z-Q904 F1000
124 L  X-639.9 RL F AUTO
125 L  Y+20 RL F AUTO
126 L  Z+50 R0 FMAX
127 L  X-1260  Y-50 FMAX
128 L  Z+5 FMAX
129 L  Z-Q904 F1000
130 L  X-1239.9 RL F AUTO
131 L  Y+20 RL F AUTO
132 L  Z+50 R0 FMAX
133 Q904 = Q904 + Q903 ; Neue Zustellung Z
134 FN 11: IF +Q904 GT +Q901 GOTO LBL "ENDE"
135 FN 9: IF +0 EQU +0 GOTO LBL "SCHLICHTEN"
136 LBL "ENDE"
137 TOOL CALL 32 Z S100
138 CYCL DEF 301 ~
    Q1998=+1
139 L  X-400  Y+70 FMAX M30
140 END PGM Abzeilen 3 Konturen MM

Zurück