Nightwing

Heidenhain iTNC 530

Hier findest Du einige Parameterprogramme für Fräsmaschinen mit der Heidenhain iTNC 530 Steuerung. Für tägliche und sich oft wiederholende Bearbeitungen kann man sich schonmal das Leben erleichtern.

« Letzter Eintrag Nächster Eintrag »

Gesamtes Werkzeugmagazin automatisch vermessen

Falls man ein grösseres Werkzeugmagazin hat und es von Zeit zu Zeit komplett durchmessen muss (sinnvoll), geht das natürlich auch mit einem kleinen Q Parameterprogramm:

wkz_magazin_vermessen.h

Code eingefügt. 
0  BEGIN PGM MAGAZIN VERMESSEN MM 
1  ;
2  Q501 = 1 ; Magazin Anfang
3  Q502 = 28 ; Magazin Ende
4  Q503 = Q502 - Q501 ; Berechnung
5  Q504 = 0 ; Reset
6  ;
7  LBL "WKZ-MESSEN"
8  FN 11: IF +Q501 GT +Q503 GOTO LBL "ENDE"
9  TOOL CALL Q501
10 FN 18: SYSREAD Q504 = ID50 NR19
11 FN 9: IF +Q504 EQU +0 GOTO LBL "WKZ-NUR-LAENGE"
12 FN 11: IF +Q504 GT +0 GOTO LBL "WKZ-RADIUS-LAENGE"
13 ;
14 LBL "WKZ-NUR-LAENGE"
15 TCH PROBE 481 WERKZEUG-LAENGE ~
    Q340=+0    ;PRUEFEN ~
    Q260=+50   ;SICHERE HOEHE ~
    Q341=+1    ;SCHNEIDENVERMESSUNG
16 Q501 = Q501 + 1
17 L  Y+0  Z-5 FMAX M92
18 FN 9: IF +0 EQU +0 GOTO LBL "WKZ-MESSEN"
19 ;
20 LBL "WKZ-RADIUS-LAENGE"
21 TCH PROBE 483 WERKZEUG MESSEN ~
    Q340=+0    ;PRUEFEN ~
    Q260=+50   ;SICHERE HOEHE ~
    Q341=+1    ;SCHNEIDENVERMESSUNG
22 Q501 = Q501 + 1
23 Q504 = 0
24 L  Y+0  Z-5 FMAX M92
25 FN 9: IF +0 EQU +0 GOTO LBL "WKZ-MESSEN"
26 ;
27 LBL "ENDE"
28 TOOL CALL 0 Z
29 FN 16: F-PRINT TNC:\Print\Magazin_vermessen.a / SCREEN:
30 L  Y+0  Z-5 FMAX M92 M30
31 END PGM MAGAZIN VERMESSEN MM

Bei Werkzeugen, die kein R im TT Offset haben (wie z.B. ein Bohrer), wird nur die Länge gemessen. Magazinplatz 48 (= der Letzte) wird ebenfalls nicht gemessen, da es sich um den 3D taster handelt...

Jetzt nur noch eine *.a Datei im Pfad TNC:\ (Pfad änderbar) mit folgendem Inhalt abspeichern:

wkz_magazin_vermessen.a

"Fertsch :-)";
" ";
"Das Vermessen der Werkzeuge ist beendet.";
" ";
M_CLOSE;

Wenn man keine Textausgabe wünscht, kann man natürlich die entsprechende Zeile auskommentieren und die Textdatei weglassen.

Zurück