Nightwing

Heidenhain iTNC 530

Hier findest Du einige Parameterprogramme für Fräsmaschinen mit der Heidenhain iTNC 530 Steuerung. Für tägliche und sich oft wiederholende Bearbeitungen kann man sich schonmal das Leben erleichtern.

« Letzter Eintrag Nächster Eintrag »

Lochkreis mit Stop nach einzelner Bearbeitung

Der Lochkreiszyklus von Heidenhain ist zwar gut, jedoch fehlt mir ein Anhalten und Freifahren auf zweiten Sicherheitsabstand nach jeder einzelnen Bohrung, um Späne am Werkzeug zu entfernen. Also flux mal selbst geschrieben:

lochkreis.h

Code eingefügt. 
0  BEGIN PGM Lochkreis MM 
1  BLK FORM 0.1 Z  X-76  Y-76  Z-132.7
2  BLK FORM 0.2  X+76  Y+76  Z+0
3  ;
4  ; Variablen fuer Bohren definieren
5  ;
6  Q10 = 38 ; Werkzeug
7  Q11 = 40 ; Vc
8  Q12 = 67.5 ; Tiefe
9  Q13 = 1.5 ; Spanbruch / Zustellung
10 ;
11 ; Variablen fuer Lochkreis definieren
12 ;
13 Q1 = 0 ; X Mittelpunkt
14 Q2 = 0 ; Y Mittelpunkt
15 Q3 = 96 ; Durchmesser
16 Q5 = 6 ; Anzahl
17 Q7 = 30 ; Startwinkel
18 ;
19 ; Ab hier nichts mehr aendern!!
20 ;
21 Q4 = Q3 / 2 ; Berechnung Radius
22 Q6 = 360 / Q5 ; Berechnung Winkel
23 Q8 = Q7 - Q6 ; Berechnung Startwinkel
24 L  Y+0  Z+0 FMAX M91
25 TOOL CALL Q10 Z S( VC = Q11 )
26 CYCL DEF 301 ~
    Q1998=+1
27 CYCL DEF 205 UNIVERSAL-TIEFBOHREN ~
    Q200=+5    ;SICHERHEITS-ABST. ~
    Q201=-Q12  ;TIEFE ~
    Q206= FU+0.1  ;VORSCHUB TIEFENZ. ~
    Q202=+Q13  ;ZUSTELL-TIEFE ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q212=+0    ;ABNAHMEBETRAG ~
    Q205=+Q13  ;MIN. ZUSTELL-TIEFE ~
    Q258=+0.5  ;VORHALTEABSTAND OBEN ~
    Q259=+0.5  ;VORHALTEABST. UNTEN ~
    Q257=+Q13  ;BOHRTIEFE SPANBRUCH ~
    Q256=+0.5  ;RZ BEI SPANBRUCH ~
    Q211=+0    ;VERWEILZEIT UNTEN ~
    Q379=+0    ;STARTPUNKT ~
    Q253=+1000 ;VORSCHUB VORPOS.
28 CC  X+Q1  Y+Q2
29 Q9 = 1 ; ZAEHLER
30 LP  PR+Q4  PA+Q8 FMAX
31 LBL "REPLAY"
32 M3 M55
33 FN 11: IF +Q9 GT +Q5 GOTO LBL "ENDE"
34 LP  PR+Q4 IPA+Q6 FMAX M99
35 Q9 = Q9 + 1
36 M140 MB MAX
37 STOP M5 M9
38 FN 9: IF +0 EQU +0 GOTO LBL "REPLAY"
39 LBL "ENDE"
40 L  Y+0  Z+0 FMAX M91
41 TOOL CALL 32 Z S100
42 CYCL DEF 301 ~
    Q1998=+1
43 L  Y+0  Z+0 FMAX M91 M30
44 END PGM Lochkreis MM

Zurück