Nightwing

Heidenhain iTNC 530

Hier findest Du einige Parameterprogramme für Fräsmaschinen mit der Heidenhain iTNC 530 Steuerung. Für tägliche und sich oft wiederholende Bearbeitungen kann man sich schonmal das Leben erleichtern.

« Letzter Eintrag Nächster Eintrag »

N Kant fräsen

Hier ein kleines Programm, um einen N Kant zu fräsen. So ist ein Vierkant / Sechskant / Achtkant kein Problem mehr, das Programm rechnet sich allein alles aus.

n-kant.h

Code eingefügt. 
0  BEGIN PGM Mehrkant MM 
1  BLK FORM 0.1 Z  X-50  Y-50  Z-50
2  BLK FORM 0.2  X+50  Y+50  Z+0
3  ;
4  ; Variablen fuer Fraesen definieren
3  ;
4  ; X / Y Nullpunkt = Mitte Teil!
3  ;
3  Q801 = 5 ; Anzahl Kanten
4  Q802 = 25 ; Schluesselweite
5  Q803 = 2 ; Eckenradius
6  Q804 = 22 ; Tiefe
7  Q805 = 5.5 ; Zustellung
8  Q806 = 5 ; Sicherheitsabstand
12 Q807 = 50 ; 2. Sicherheitsabstand Z
13 Q808 = 1 ; Werkzeug
14 Q809 = 220 ; Vc
15 Q810 = 8 ; M Befehl Kuehlung
16 Q811 = 7 ; M Befehl Innenkuehlung
17 Q812 = 1000 ; Vorschub Zustellung
18 Q813 = 1250 ; Vorschub Fraesen
29 ;
30 ; Ab hier nichts mehr aendern!!
31 ;
34 TOOL CALL Q808 Z S( VC = Q809 )
13 CYCL DEF 301 ~
    Q1998=+1
14 Q814 = ( Q108 * 2 ) + ( Q802 / 2 )
15 Q815 = 0
16 Q816 = Q801 - 2
17 Q817 = 180 / Q801
18 FN 7: Q818 = COS +Q817
19 Q819 = ( Q802 / 2 ) / Q818
20 Q820 = Q817 * 2
21 Q821 = Q802 / 2
22 L  X+Q814  Y+0 FMAX M3 MQ810
23 L  Z+Q806 FMAX MQ811
25 LBL "FRAESEN"
26 Q815 = Q815 + Q805
27 FN 11: IF +Q815 GT +Q804 GOTO LBL "ENDE"
28 L  Z-Q815 FQ812
29 CC  X+0  Y+0
30 LP  PR+Q821  PA+0 RL FQ813
31 LP  PR+Q819  PA-Q817
32 RND RQ803
33 LBL "KONTUR"
34 LP  PR+Q819 IPA-Q820 RL FQ813
35 RND RQ803
36 CALL LBL "KONTUR" REPQ816
37 LP  PR+Q821  PA+0
38 L  X+Q814  Y+0 FQ813
39 CALL LBL "FRAESEN"
40 LBL "ENDE"
41 TOOL CALL 0 Z S100
42 L  X+250 IY-250 FMAX M30
43 END PGM Mehrkant MM

Zurück